Dx21 - UDC

Select Language: | |

Class clsISBN

	Public Function IsValidISBN(ByVal strNumber)
		If IsValidISBN10(strNumber) Then
			IsValidISBN = True
		ElseIf IsValidISBN13(strNumber) Then
			IsValidISBN = True
		Else
			IsValidISBN = False
		End If
	End Function

	Public Function IsValidISBN10(ByVal strNumber)
		strNumber= StripISBN(strNumber)
		
		If ValidISBN(strNumber) = False Then 
			IsValidISBN10 = False
			Exit Function
		End If
		
		Dim intStack: intStack = 0
		Dim I
		
		For I  = 1 To 9
			intStack = intStack + (CInt(Mid(strNumber,I,1) * (I)))
		Next
		
		Dim Check_Digit:  Check_Digit = Right(strNumber, 1)
		If Check_Digit = "X" Then Check_Digit = "10"
		
		If intStack Mod 11 = CInt(Check_Digit) Then IsValidISBN10 = True Else IsValidISBN10 = False
	End Function
	
	Public Function IsValidISBN13(strNumber)
		strNumber= StripISBN(strNumber)
	
		If ValidISBN(strNumber) = False Then 
			IsValidISBN13 = False
			Exit Function
		End If
		
		Dim intStack: intStack = 0
		Dim I
		Dim bEven:	bEven = False
		
		For I  = 13 To 1 Step -1
			If bEven Then
				intStack = intStack + (CInt(Mid(strNumber,I, 1)) * 3)
			Else
				intStack = intStack +  CInt(Mid(strNumber,I, 1))
			End If
			bEven = Not bEven
		Next
		
		If intStack Mod 10 = 0 Then IsValidISBN13 = True Else IsValidISBN13 = False
	End Function
	
	Private Function StripISBN(strNumber)
		Dim objRE:	Set objRE = New RegExp
		
		With objRE
			.Global = True
			.IgnoreCase = True
			.Pattern = "[\.\-\s]"
		End With
		
		StripISBN = objRE.Replace(strNumber,"")
	End Function
	
	Private Function ValidISBN(strNumber)
		Dim objRE:	Set objRE = New RegExp
		
		With objRE
			.Global = True
			.IgnoreCase = True
		End With
		
		If Len(strNumber) = 10 Then
			objRE.Pattern ="^([0-9]{9})(X|[0-9])$"
		Else
			objRE.Pattern="^([0-9]{13})$"
		End If
		
		ValidISBN = objRE.Test(strNumber)
	End Function
End Class

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2010 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 9/8/2010 10:26:34 PM for Unknown

User Defined Class Library