Dx21 - UDC

Select Language: | |

Class clsSMSTrace32Log	
	'////////////////////////////////////////////////////
	'SMS Trace 32 Log Formatting Class
	'File Name: clsSMSTrace32Log
	'Script Version: 1.0.1
	'Last Edit: 8/18/2005
	'Developer: Dx21, LLC
	'////////////////////////////////////////////////////
	'*Best viewed using Admin Script Editor (http://www.dx21.com/SCRIPTING/VBSCRIPT/INDEX.ASP)

	'-------------------------------------------------------------
	'REGION Internal objects and variables
	
	Private objFSO
	
	Private strFileName, strSourceScript, strComponent, bContext, intOffset
	
	'ENDREGION
	
	'-------------------------------------------------------------
	'REGION Intrinsic Functions
	
	Private Sub Class_Initialize()		
		On Error Resume Next
		
		'Create 
		Set objFSO = CreateObject("Scripting.FileSystemObject")
		If Err.number <> 0 Then
			Err.Raise vbObjectError + 2, clsName, "Error creating the FileSystemObject."
			Err.Clear 
			Class_Terminate
		End If
		
		'Set default values
		strSourceScript = WScript.ScriptName
		strComponent = appName
		intOffset = (GetTimeZoneBias)*-1
	End Sub
	
	Private Sub Class_Terminate()
		On Error Resume Next
		
		Set objFSO = Nothing
	End Sub
	
	'ENDREGION
	
	'-------------------------------------------------------------
	'REGION Property Get - ReadOnly
	
	Property Get appVersion()
		appVersion = "1.0.1"
	End Property
	
	Property Get appName()
		appName = "clsSMSTrace32Log"
	End Property
	
	'ENDREGION
	
	'-------------------------------------------------------------
	'REGION Property Read/Write
	
	Property Get LogFileName()
		LogFileName = strFileName
	End Property
	
	Property Let LogFileName(strLogFile)
		Dim strFolder
		
		If Left(strLogFile, 2) <> "\\" And Mid(strLogFile, 2, 2) <> ":\" Then
			Err.Raise vbObjectError + 3, clsName, "Invalid file name specified."
			Exit Property
		End If
		
		strFolder = Left(strLogFile, InStrRev(strLogFile, "\")-1)
		If objFSO.FolderExists(strFolder) = False Then
			Err.Raise vbObjectError + 4, clsName, "Specified file folder could not be located."
			Exit Property
		End If
		
		strFileName = strLogFile
	End Property
	
	Property Let Component(strCompName)
		strComponent = strCompName
	End Property	
	
	Property Get Component
		Component = strComponent
	End Property
	
	Property Let ShowContext(bYesNo)
		bContext = (bYesNo = True)
	End Property
	
	Property Get ShowContext()
		ShowContext = bContext
	End Property
	
	Property Let Source(strSource)
		strSourceScript = strSource
	End Property
	
	Property Get Source
		Source = strSourceScript
	End Property
	
	'ENDREGION

	'-------------------------------------------------------------
	'REGION Public Functions
	
	Public Sub LogEvent(strMessage, intType, dblThread, strContext)
		Dim strTime, strDate
		Dim tsFile 
		
		If strFileName = "" Then
			Err.Raise vbObjectError + 5, clsName, "Log file not specified."
			Exit Sub
		End If
		
		'Format Message
		strMessage = "<![LOG[" & strMessage & "]LOG]!>"
		
		'Format Time
		If Len(CStr(Hour(Now))) = 1 Then strTime = "0" & Hour(Now) Else strTime = Hour(Now)
		If Len(CStr(Minute(Now))) = 1 Then strTime = strTime & ":0" & Minute(Now) Else strTime = strTime & ":" & Minute(Now)
		If Len(CStr(Second(Now))) = 1 Then strTime = strTime & ":0" & Second(Now) Else strTime = strTime & ":" & Second(Now)
		strTime = strTime & ".000"
		If intOffset > -1 Then strTime = strTime & "+"
		strTime = strTime & CStr(intOffset)
		
		'Format Date
		If Len(CStr(Month(Now))) = 1 Then strDate = "0" & Month(Now) Else strDate = Month(Now)
		If Len(CStr(Day(Now))) = 1 Then strDate = strDate & "-0" & Day(Now) Else strDate = strDate & "-" & Day(Now)
		strDate = strDate &"-" &  Year(Now)
		
		On Error Resume Next
		
		Set tsFile = objFSO.OpenTextFile(strFileName,8, True,-2)
		If Err.number <> 0 Then
			Err.Raise vbObjectError + 6, clsName, "Unable to open specified log file."
			Err.Clear 
			Exit Sub
		End If
		
		strMessage = strMessage & "<"
			strMessage = strMessage & "time='" & strTime & "' "
			strMessage = strMessage & "date='" & strDate & "' "
			strMessage = strMessage & "component='" & strComponent
				If bContext Then strMessage = strMessage & ":" & strContext
				strMessage = strMessage & "' "
			strMessage = strMessage & "context='" & strContext & "' "
			strMessage = strMessage & "type='" & intType & "' "
			strMessage = strMessage & "thread='" & dblThread & "' "
			strMessage = strMessage & "file='" & strSourceScript & "'"
		strMessage = strMessage & ">"
		
		strMessage = Replace(strMessage,"'",Chr(34))
		
		tsFile.WriteLine strMessage
		tsFile.Close
		
		Set tsFile = Nothing
	End Sub
	
	'ENDREGION
	
	'-------------------------------------------------------------
	'REGION Private Functions
	
	Private Function GetTimeZoneBias()
		Const wbemFlagReturnImmediately = &h10
		Const wbemFlagForwardOnly = &h20
	
		Dim objWMI, colOS, objOS, colTZ, objTZ, intBias
		
		'On Error Resume Next
		Set objWMI = GetObject("winmgmts:\\.\root\CIMV2")
		
		If Err.number = 0 Then 
			Set colOS = objWMI.ExecQuery("SELECT DayLightinEffect FROM Win32_ComputerSystem", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)
			Set colTZ = objWMI.ExecQuery("SELECT Bias, DaylightBias, StandardBias FROM Win32_TimeZone", "WQL", wbemFlagReturnImmediately + wbemFlagForwardOnly)
		
			For Each objOS In colOS
				For Each objTZ In colTZ
					intBias = objTZ.bias
					If objOS.DayLightinEffect Then
						GetTimeZoneBias = intBias - objTZ.DaylightBias
					Else
						GetTimeZoneBias = intBias - objTZ.StandardBias
					End If
				Next
			Next
		Else
			Err.Clear 
			GetTimeZoneBias = Null
		End If
		
		Set objOS = Nothing
		Set colOS = Nothing
		Set objTZ = Nothing
		Set colTZ = Nothing
		Set objWMI = Nothing
	End Function
	
	'ENDREGION
	
	'////////////////////////////////////////////////////
	'Copyright  2005 Dx21, LLC
	'	a Washingtion Limited Liability Company
	'	All Rights Reserved
	'
	'Use of this script is subject to the terms and conditions
	'as listed in our public Copyright and Disclamer statments.
	'Those statements must be agreed to prior to use of this
	'script:
	'
	'http://www.dx21.com/home/tos/tos.asp
	'////////////////////////////////////////////////////

End Class

Imports System.Text.RegularExpressions
Imports System.Management

'////////////////////////////////////////////////////
'SMS Trace 32 Log Formatting Class
'File Name: clsSMSTrace32Log
'Script Version: 1.0.1
'Last Edit: 10/23/2006
'Developer: Dx21, LLC
'////////////////////////////////////////////////////

Public Class clsSMSTrace32
    Private strFileName, strSourceScript, strComponent As String
    Private bContext As Boolean
    Private intOffset As Integer

    Public Enum STATUS
        clsNORMAL = 1
        clsCAUTION = 2
        clsERROR = 3
    End Enum

    Public Sub New()
        'Set default values
        strSourceScript = ".NET Application"
        strComponent = Application.ProductName
        intOffset = (GetTimeZoneBias()) * -1
    End Sub

    '-------------------------------------------------------------
    ReadOnly Property clsVersion() As String
        Get
            clsVersion = "1.0.0"
        End Get
    End Property

    ReadOnly Property clsName() As String
        Get
            clsName = "clsSMSTrace32Log"
        End Get
    End Property

    '-------------------------------------------------------------
    Property LogFileName() As String
        Get
            LogFileName = strFileName
        End Get
        Set(ByVal strFile As String)
            'Verify File Name (Simple)
            Dim objRE As Regex = New Regex("(\\\\|:\\)")
            If objRE.IsMatch(strFile) = False Then
                Err.Raise(vbObjectError + 3, clsName, "Invalid file name specified.")
                Exit Property
            End If

            'Can we open the file?
            If My.Computer.FileSystem.FileExists(strFile) = False Then
                Try
                    Dim tsFile As System.IO.StreamWriter = New System.IO.StreamWriter(strFile)
                    tsFile.Close()
                    strFileName = strFile
                Catch ex As Exception
                    Err.Raise(vbObjectError + 4, clsName, "Specified file folder could not be located.")
                    Exit Property
                End Try
            End If
        End Set
    End Property

    Property Component() As String
        Get
            Component = strComponent
        End Get
        Set(ByVal strCompName As String)
            strComponent = strCompName
        End Set
    End Property

    Property ShowContext() As Boolean
        Get
            ShowContext = bContext
        End Get
        Set(ByVal bState As Boolean)
            bContext = bState
        End Set
    End Property

    Property Source() As String
        Get
            Source = strSourceScript
        End Get
        Set(ByVal strSource As String)
            strSourceScript = strSource
        End Set
    End Property

    '-------------------------------------------------------------

    Public Sub LogEvent(ByVal strMessage As String, ByVal intStatus As STATUS, ByVal dblThread As Double, ByVal strContext As String)
        Dim strTime, strDate As String
        Dim tsFile As System.IO.StreamWriter

        If strFileName = "" Then
            Err.Raise(vbObjectError + 5, clsName, "Log file not specified.")
            Exit Sub
        End If

        'Format Message
        strMessage = "<![LOG[" & strMessage & "]LOG]!>"

        'Format Time
        If Len(CStr(Hour(Now))) = 1 Then strTime = "0" & Hour(Now) Else strTime = Hour(Now).ToString
        If Len(CStr(Minute(Now))) = 1 Then strTime = strTime & ":0" & Minute(Now) Else strTime = strTime & ":" & Minute(Now)
        If Len(CStr(Second(Now))) = 1 Then strTime = strTime & ":0" & Second(Now) Else strTime = strTime & ":" & Second(Now)
        strTime = strTime & ".000"
        If intOffset > -1 Then strTime = strTime & "+"
        strTime = strTime & CStr(intOffset)

        'Format Date
        If Len(CStr(Month(Now))) = 1 Then strDate = "0" & Month(Now) Else strDate = Month(Now).ToString
        If Len(CStr(Microsoft.VisualBasic.DateAndTime.Day(Now).ToString)) = 1 Then strDate = strDate & "-0" & Microsoft.VisualBasic.DateAndTime.Day(Now).ToString Else strDate = strDate & "-" & Microsoft.VisualBasic.DateAndTime.Day(Now).ToString
        strDate = strDate & "-" & Year(Now)

        Try
            tsFile = New System.IO.StreamWriter(strFileName)
        Catch ex As Exception
            Err.Raise(vbObjectError + 6, clsName, "Unable to open specified log file.")
            Exit Sub
        End Try

        strMessage = strMessage & "<"
        strMessage = strMessage & "time='" & strTime & "' "
        strMessage = strMessage & "date='" & strDate & "' "
        strMessage = strMessage & "component='" & strComponent
        If bContext Then strMessage = strMessage & ":" & strContext
        strMessage = strMessage & "' "
        strMessage = strMessage & "context='" & strContext & "' "
        strMessage = strMessage & "type='" & intStatus & "' "
        strMessage = strMessage & "thread='" & dblThread & "' "
        strMessage = strMessage & "file='" & strSourceScript & "'"
        strMessage = strMessage & ">"

        strMessage = Replace(strMessage, "'", Chr(34))

        tsFile.WriteLine(strMessage)
        tsFile.Close()

        tsFile = Nothing
    End Sub

    'ENDREGION

    '-------------------------------------------------------------
    'REGION Private Functions

    Private Function GetTimeZoneBias() As Integer
        Dim objOS As System.Management.ManagementObjectSearcher
        objOS = New ManagementObjectSearcher("SELECT DayLightinEffect FROM Win32_ComputerSystem")

        Dim objTZ As System.Management.ManagementObjectSearcher
        objTZ = New ManagementObjectSearcher("SELECT Bias, DaylightBias, StandardBias FROM Win32_TimeZone")

        Dim colOS As ManagementObjectCollection = objOS.Get()
        Dim colTZ As ManagementObjectCollection = objTZ.Get()

        Dim memOS, memTZ As ManagementObject
        Dim intBias As Integer

        For Each memOS In colOS
            For Each memTZ In colTZ
                intBias = CInt(memTZ("bias"))
                If CBool(memOS("DayLightinEffect")) Then
                    GetTimeZoneBias = intBias - CInt(memTZ("DaylightBias"))
                Else
                    GetTimeZoneBias = intBias - CInt(memTZ("StandardBias"))
                End If
            Next
        Next
    End Function
End Class

'////////////////////////////////////////////////////
'Copyright © 2005, 2006 Dx21, LLC
'	a Washingtion Limited Liability Company
'	All Rights Reserved
'
'Use of this script is subject to the terms and conditions
'as listed in our public Copyright and Disclamer statments.
'Those statements must be agreed to prior to use of this
'script:
'
'http://www.dx21.com/home/tos/tos.asp
'////////////////////////////////////////////////////

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2010 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 9/9/2010 11:56:54 AM for Unknown

User Defined Class Library