Dx21 - Script Library

Home

eZine

Coding

Software

Network Admin.

Home > Coding > Libraries > Script Library > View Item Info

	Back
	Scripting References

Toggle WDS Server Tracing

If you are managing Windows Deployment Services Server in Windows Server 2008, you may find that you need to troubleshoot via logs. This script facilitates enabling or disabling WDSServer tracing by updating the registry flag that manages the process and then restarting the WDSServer service. Can be run against a remote computer, silently, and with command line switches.

Option Explicit

'////////////////////////////////////////////////////
'WDS Server Tracing Toggle
'File Name: ToggleWDSServer.vbs
'Script Version: 1.0.0
'Last Edit: 4/15/2009
'Developer: Dx21, LLC
'////////////////////////////////////////////////////

'Constants used to specify which hive to write to
Const HKEY_CLASSES_ROOT 	= &H80000000
Const HKEY_CURRENT_USER 	= &H80000001
Const HKEY_LOCAL_MACHINE 	= &H80000002
Const HKEY_USERS 			= &H80000003
Const HKEY_CURRENT_CONFIG 	= &H80000005
'Constants used to specify write type
Const REG_SZ        = 1
Const REG_EXPAND_SZ = 2
Const REG_BINARY    = 3
Const REG_DWORD     = 4
Const REG_MULTI_SZ  = 7

Const REGROOT = "SOFTWARE\Microsoft\Tracing\WDSSERVER"
Const SERVICE = "WDSServer"
Const LOCALREG = "SOFTWARE\Dx21, LLC\ToggleWDSServer Script"

Dim objWMI, colSvc, objSvc
Dim objReg
Dim strComputer, intEnableFileTracing
Dim bTracingWasOn, bUpdatedRegistry, bSilent

'Ensure correct engine
If InStr(1, UCase(WScript.FullName), "CSCRIPT.EXE") = 0 Then
	Dim objShell: Set objShell = CreateObject("WScript.Shell")
	Dim strCmdLine: strCmdLine = "cmd /c CSCRIPT.EXE " & Chr(34) & WScript.ScriptFullName & Chr(34)
	If WScript.Arguments.Count > 0 Then 
		Dim strArgs, objA
		For Each objA In WScript.Arguments
			strCmdLine = strCmdLine & " " & objA
		Next
	End If
	objShell.Run strCmdLine, 1, False
	CleanEnv 0
End If

Set objReg = New clsRegEdit

'Command line passed?
If WScript.Arguments.Named.Count > 0 Then
	If WScript.Arguments.Named.Exists("M") Then strComputer = WScript.Arguments.Named.Item("M")
	If WScript.Arguments.Named.Exists("S") Then bSilent = True
	If WScript.Arguments.Named.Exists("?") Then
		MsgBox "'WDS Server Tracing Toggle' command line options:" & vbCr & _
			"/M:[ComputerName] - name of computer to toggle" & vbCr & _
			"/S - Run silent" & vbCr & _
			"/? - Shows this dialog" & vbCr & vbCr & _
			"Example: ToggleWDSServer.vbs /M:SFRWDS", _
			vbOKOnly+vbInformation,"Help"
		CleanEnv 0
	End If
End If

'Get Last Used Computer Name
If strComputer = "" Then
	strComputer = objReg.ReadRegEntry(".",HKEY_CURRENT_USER,LOCALREG,"strComputer",REG_SZ)
	If TypeName(strComputer) = "Null" Then strComputer = ""
End If

'Prompt for computer
If bSilent = False AND Not WScript.Arguments.Named.Exists("M") Then
	strComputer = InputBox("What server would you like to toggle? Use '.' for local.","Computer To Toggle",strComputer)
	If Len(Trim(strComputer)) = 0 Then CleanEnv 0
Else
	If strComputer = "" Then CleanEnv 0
End If

'Save as default
objReg.WriteRegEntry ".",HKEY_CURRENT_USER,LOCALREG,"strComputer",strComputer,REG_SZ

'Verify Service
If Not bSilent Then WScript.Echo "Attempting to connect to " & strComputer
Set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
Set colSvc = objWMI.ExecQuery("SELECT * FROM Win32_Service WHERE Name='" & SERVICE & "'")

If colSvc.Count = 0 Then
	'Not Found
	If Not bSilent Then MsgBox "The 'Windows Deployment Services Server' was not found on '" & strComputer & "'.",vbOKOnly+vbInformation,"Nothing To Do"
	CleanEnv 0
End If

'WDSServer Logging
If Not bSilent Then WScript.Echo "Determining current tracing status on machine"
intEnableFileTracing = objReg.ReadRegEntry(strComputer,HKEY_LOCAL_MACHINE,REGROOT,"EnableFileTracing",REG_DWORD)
If intEnableFileTracing = 1 Then
	'Tracing Enabled, disable
	If Not bSilent Then WScript.Echo "Attempting to disable tracing"
	bUpdatedRegistry = objReg.WriteRegEntry(strComputer,HKEY_LOCAL_MACHINE,REGROOT,"EnableFileTracing",0,REG_DWORD)
	bTracingWasOn = "off"
Else
	'Tracing Disabled, enable
	If Not bSilent Then WScript.Echo "Attempting to enable tracing"
	bUpdatedRegistry = objReg.WriteRegEntry(strComputer,HKEY_LOCAL_MACHINE,REGROOT,"EnableFileTracing",1,REG_DWORD)
	bTracingWasOn = "on"
End If

'WDSServer Service
If bUpdatedRegistry = 0 Then
	If Not bSilent Then WScript.Echo "Tracing setting complete.  Restarting WDS Service"
	If RestartService = True Then
		if not bsilent Then MsgBox "WDS Tracing was toggled " & bTracingWasOn & " and the service restarted as expected.", vbOKOnly+vbInformation,"Done"
		CleanEnv 0
	Else
		if not bsilent Then MsgBox "Although WDS Tracing was toggled " & bTracingWasOn & ", the service was unable to be restarted and requires manual intervention.", vbOKOnly+vbError,"Done"
		CleanEnv -2
	End If
Else
	if not bsilent Then MsgBox "Unable to update the remote computer's registry, nothing was done.", vbOKOnly+vbCritical,"Done"
	CleanEnv -1
End If

Sub CleanEnv(intExitCode)
	On Error Resume Next: Err.Clear
	
	Set objWMI = Nothing
	Set colSvc = Nothing
	Set objSvc = Nothing
	
	WScript.Quit intExitCode
End Sub

Function RestartService()
	' This function modified from the book:
	' "Active Directory, Third Edition" 
	' ISBN: 0-596-10173-2

Dim objServiceList, objService
	
	On Error Resume Next: Err.Clear
	
	'Stop dependent services
	Set objServiceList = objWMI.ExecQuery("Associators of " _
	                 & "{Win32_Service.Name='" & SERVICE & "'} Where " _
	                 & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
	                 
	For Each objService In objServiceList
		If Not bSilent Then WScript.Echo "STOPPING DEPENDENT SERVICE: " & objService.Name
	    objService.StopService()
	Next
	WScript.Sleep 10000   ' Pause to allow services to stop
	If Err.Number <> 0 Then 
		RestartService = False
		Err.Clear
		Exit Function
	End If
	   
	' Stop target service
	Set objService = objWMI.Get("Win32_Service.Name='" & SERVICE & "'")
	If Not bSilent Then WScript.Echo "STOPPING PRIMARY SERVICE: " & objService.Name
	objService.StopService()
	
	WScript.Sleep 10000   ' Pause to allow service to stop
	If Err.Number <> 0 Then 
		RestartService = False
		Err.Clear
		Exit Function
	End If
	   
	' Start target service
	Set objService = objWMI.Get("Win32_Service.Name='" & SERVICE & "'")
	If Not bSilent Then WScript.Echo "STARTING PRIMARY SERVICE: " & objService.Name
	objService.StartService()
	WScript.Sleep 10000   ' Pause to allow service to start
	If Err.Number <> 0 Then 
		RestartService = False
		Err.Clear
		Exit Function
	End If
	
	' Start dependent services
	Set objServiceList = objWMI.ExecQuery("Associators of " _
	                 & "{Win32_Service.Name='" & SERVICE & "'} Where " _
	                 & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
	For Each objService In objServiceList
		If Not bSilent Then WScript.Echo "STARTING DEPENDENT SERVICE: " & objService.Name
	    objService.StartService()
	Next
	If Err.Number <> 0 Then 
		RestartService = False
		Err.Clear
		Exit Function
	End If
	
	RestartService = True
End Function

Class clsRegEdit	
	'////////////////////////////////////////////////////
	'WMI Registry Manipulations Class
	'File Name: clsRegEdit
	'Script Version: 1.0.0
	'Last Edit: 9/1/2005
	'Developer: Dx21, LLC
	'////////////////////////////////////////////////////
	
	'---------------------------------------------------------------------------------
	'Properties
	
	Property Get clsVersion
		clsVersion = "1.0.0"
	End Property	
	
	'---------------------------------------------------------------------------------
	'Private Functions
	
	Private Function ConnectToComputer(ByRef objR, strComputer)
		On Error Resume Next
		
		Set objR = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
		ConnectToComputer = (Err.number = 0)
		Err.Clear 
	End Function	
	
	Private Function HexToDec(HexValue)
	'Converts A Hex number into a Decimal value
		Const HexBase = "0123456789ABCDEF"
	
		Dim Sum, DigitCount, MultiBase
		Dim Index, HexDigit, RetVal, HexPosition
	
		Sum = 0
		DigitCount = 0
		MultiBase = 1
	
		For Index = Len(HexValue) To 1 Step -1
			HexDigit = Mid(HexValue, Index, 1)
			HexPosition = InStr(1, HexBase, HexDigit)-1
			RetVal = RetVal + (HexPosition*MultiBase)
			MultiBase = MultiBase * 16
		Next
	
		HexToDec = RetVal
	End Function
	
	Private Function DelKeyEnum(ByVal dblRegHive, ByVal strKeyPath, ByRef objWMIReg)
		Const vbVarArray = 8204
		
		Dim colKeys, objKey, strNewKey
		Dim intRetVal
		
		objWMIReg.EnumKey dblRegHive, strKeyPath, colKeys
	
		If VarType(colKeys) = vbVarArray Then
			For Each objKey In colKeys
				'Format Display
				strNewKey = strKeyPath & "\" & objKey
	
				'Enumerate children
				If DelKeyEnum(dblRegHive, strNewKey, objWMIReg) = False Then
					DelKeyEnum = False
					Exit Function
				End If
			Next
		End If
		
		intRetVal = objWMIReg.DeleteKey(dblRegHive, strKeyPath)
		Select Case intRetVal
			Case 0
				'The registry key was deleted successfully.
				DelKeyEnum = True
			Case 2
				'The registry key was not found on this system.
				DelKeyEnum = True
			Case 5
				'The registry key could not be removed.  Access Denied.
				DelKeyEnum = False
			Case Else
				'Unknown error code
				DelKeyEnum = False
		End Select
	End Function	
	
	'---------------------------------------------------------------------------------
	'Public Functions

Public Function ReadRegEntry(strComputer, dblHive, strPath, strKey, dblType)	
		Const REG_SZ        = 1
		Const REG_EXPAND_SZ = 2
		Const REG_BINARY    = 3
		Const REG_DWORD     = 4
		Const REG_MULTI_SZ  = 7
		
		Dim objReg
		Dim RetVal
		
		'Connect to Computer
		If ConnectToComputer(objReg, strComputer) = False Then
			Err.Raise vbObjectError+1,"clsRegEdit","Unable to connect to remote computer."
			ReadRegEntry = Null
			Exit Function
		End If
	
		'Determine type to Read
		Select Case dblType
			Case REG_EXPAND_SZ
				objReg.GetExpandedStringValue dblHive, strPath, strKey, RetVal
			Case REG_BINARY
				objReg.GetBinaryValue dblHive, strPath, strKey, RetVal
			Case REG_DWORD
				objReg.GetDWORDValue dblHive, strPath, strKey, RetVal
			Case REG_MULTI_SZ
				objReg.GetMultiStringValue dblHive, strPath, strKey, RetVal
			Case Else
				objReg.GetStringValue dblHive, strPath, strKey, RetVal
		End Select
	
		ReadRegEntry = RetVal
	
		Set objReg = Nothing
	End Function
	
	Public Function WriteRegEntry(strComputer, dblHive, strPath, strKey, strValue, dblType)
		Const REG_SZ        = 1
		Const REG_EXPAND_SZ = 2
		Const REG_BINARY    = 3
		Const REG_DWORD     = 4
		Const REG_MULTI_SZ  = 7
		
		Dim intRetVal, intCount
		Dim arrBIN
		Dim objReg
	
		'Connect to Computer
		If ConnectToComputer(objReg, strComputer) = False Then
			Err.Raise vbObjectError+1,"clsRegEdit","Unable to connect to remote computer: " & err.Description
			WriteRegEntry = False
			Exit Function
		End If		
		
		'Writes can fail if the key is not present - verify the key
		objReg.CreateKey dblHive, strPath
	
		Select Case dblType
			Case REG_SZ
				'String Value
				intRetVal = objReg.SetStringValue(dblHive, CStr(strPath), CStr(strKey), CStr(strValue))
			Case REG_EXPAND_SZ
				'Expanded String
				intRetVal = objReg.SetExpandedStringValue(dblHive, CStr(strPath), CStr(strKey), CStr(strValue))
			Case REG_BINARY
				'Binary Value - The data must be passed as a numeric array
				'We assume the data will be passed as integers or HEX values
				'We also assume the seperation character to be a |
				arrBIN = Split(strValue, "|")
				For intCount = 0 To UBound(arrBIN)
					If IsNumeric(arrBIN(intCount)) Then
						arrBIN(intCount) = CInt(arrBIN(intCount))
					Else
						arrBIN(intCount) = CInt(HexToDec(arrBIN(intCount)))
					End If
				Next
	
				intRetVal = objReg.SetBinaryValue(dblHive, CStr(strPath), CStr(strKey), arrBIN)
				Erase arrBIN
			Case REG_DWORD
				'DWord Value
				intRetVal = objReg.SetDWORDValue(dblHive,CStr(strPath), CStr(strKey), CLng(strValue))
			Case REG_MULTI_SZ
				'Multi-String Value
				'We assume the seperation character to be a |
				arrBIN = Split(strValue, "|")
	
				intRetVal = objReg.SetMultiStringValue(dblHive,CStr(strPath), CStr(strKey), arrBIN)
				Erase arrBIN
		End Select
	
		WriteRegEntry = intRetVal
		Set objReg = Nothing
	End Function
	
	Public Function DeleteRegKey(strComputer, dblHive, strPath)
		Dim objReg
		
		'Connect to Computer
		If ConnectToComputer(objReg, strComputer) = False Then
			Err.Raise vbObjectError+1,"clsRegEdit","Unable to connect to remote computer: " & err.Description
			DeleteRegKey = False
			Exit Function
		End If
		
		DeleteRegKey = DelKeyEnum(dblHive, strPath, objReg)
		
		Set objReg = Nothing
	End Function
	
	Public Function DeleteRegEntry(strComputer, dblHive, strPath, strKey)
		Dim objReg, intRetVal
	
		'Connect to Computer
		If ConnectToComputer(objReg, strComputer) = False Then
			Err.Raise vbObjectError+1,"clsRegEdit","Unable to connect to remote computer: " & err.Description
			DeleteRegEntry = False
			Exit Function
		End If
		
		On Error Resume Next
		
		intRetVal = objReg.DeleteValue(dblHive, strPath, strKey)
		DeleteRegEntry = ((intRetVal = 0) And (Err.number=0))
		Err.Clear
	End Function			
	
	'*********************************************************************************
	'
	'////////////////////////////////////////////////////
	'Copyright  2005 Dx21, LLC
	'	a Washingtion Limited Liability Company
	'	All Rights Reserved
	'
	'Use of this script is subject to the terms and conditions
	'as listed in our public Copyright and Disclamer statments.
	'Those statements must be agreed to prior to use of this
	'script:
	'
	'http://www.dx21.com/home/tos/tos.asp
	'////////////////////////////////////////////////////
	'
	'REGION VERSION HISTORY:
	'
	'1.0.0	- 9/1/2005
	'	Initial Release
	'
	'ENDREGION
End Class

'*********************************************************************************
'
'////////////////////////////////////////////////////
'Copyright 2009 Dx21, LLC
'	a Washingtion Limited Liability Company
'	All Rights Reserved
'
'Use of this script is subject to the terms and conditions
'as listed in our public Copyright and Disclamer statments.
'Those statements must be agreed to prior to use of this
'script:
'
'http://dx21.com/home/tos.aspx
'////////////////////////////////////////////////////
'
'VERSION HISTORY:
'
'1.0.0	- 4/15/2009
'	Initial Release

Unless otherwise noted, this code is licensed according to the terms and conditions listed in our copyright notice.

Last Modification:
4/15/2009

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2010 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 9/2/2010 8:11:29 PM for Unknown