Dx21 - Script Library

Home

eZine

Coding

Software

Network Admin.

Home > Coding > Libraries > Script Library > View Item Info

	Back
	Scripting References

Backup File Removal

This script was developed to assist in removing unneeded backup files from a DOCSOpen Document Store. When users of Word have the automatic backup feature turned on, a duplicate file is created. Because many of these files are redundant and only take up space, this script is used to parse through the drive document store, filtering out each of the backup files, then making decisions on what to do with that file. The script test for the existence of the original file, then sees if the original is damaged or out of date. If either of these conditions are true, the script replaces the original with the backup - else it removes the backup. Script demonstrates recursive functions, and makes heavy use of the FileSystemObject.

Option Explicit

' Syntax
' CSCRIPT.EXE DOBFCU.VBS {Path to Store} [Path/Name to Log File]
' Log file is optional, path to docs store top directory required.

' Date Last Modified: 10:24 AM 10/10/2000
' Contact: Jase T. Wolfe, SFR

' FLOW:
'	Determine Environment
'	Hook to Main Folder
'	Parse through each folder under the main folder
' 		parse through each file in the folder
'		Look for "Backup of..." files, discover real name
'		Look for real file
'		If Real File Exists
'			Determine if real file is greater than 0KB
'			YES -> Delete Backup File
'			NO -> Replace it with backup file
'		else
'			Replace it with backup file
'

Dim FSys		' File System Object
Dim wshShell		' Scripting Shell Environment
Dim DocsStore		' Location of DocsStore
Dim Counter		' Index Counter
Dim LogFile		' Log File Path/name
Dim ByteCount		' File Size Total
Dim RecoverCount	' Recovered Document Count
Dim DeleteCount		' Deleted File Count
Dim oWS			' WScript Object
Dim LogFileName 	' Log File Name

' Initialize Objects and global variables
Set oWS = WScript
Set FSys = CreateObject("Scripting.FileSystemObject")
Set wshShell = WScript.CreateObject("WScript.Shell")

'Verify running environment
If UCase(Right(WScript.FullName, Len(WScript.FullName)-InStrRev(WScript.FullName,"\"))) <> "CSCRIPT.EXE" Then
          wshShell.Run "CSCRIPT.EXE " & Chr(34) & WScript.ScriptFullName & Chr(34)
          ClearEnvironment
          WScript.Quit
End If

RecoverCount = 0
DeleteCount = 0

' Extract arguments from command line - being an internal script, there is no error checking here
if oWS.Arguments.Count > 0 Then
	DocsStore = oWS.Arguments(0)
end if

if oWS.Arguments.Count > 1 Then
	LogFileName = oWS.Arguments(1)
end if

' If there isn't a directory to the DOCSStore then we exit out
If DocsStore = "" then
	WScript.Echo "SYNTAX:" 
	WScript.Echo 
	WScript.Echo "CSCRIPT.EXE DOBFCU.VBS {Path to Store} [Path/Name to Log File]" 
	WScript.Echo 
	WScript.Echo "Log file is optional, path to docs store top directory required."
	WScript.Quit
end if

' If the directory entered is wrong:
If FSys.FolderExists(DocsStore) = False Then
	WScript.Echo "The Directory specified as the DOCSOpen Store can not be located.  This utility will now exit."
	WScript.Quit
End If

' If we specified a Log File, set it up
if LogFileName <> "" then
	Set LogFile = FSys.OpenTextFile(LogFileName,2,-2)

LogFile.WriteLine "DOCSOpen Backup File Recovery Utility"
	LogFile.WriteLine "Start Time: " & Now()
	LogFile.WriteLine "-----------------------------------------------------------------"
	LogFile.WriteBlankLines 1
end if

' Begin recurrsive directory walk
ParseFolder DocsStore

' Close up optional log
if LogFileName <> "" then
	LogFile.WriteBlankLines 1
	LogFile.WriteLine "-----------------------------------------------------------------"
	LogFile.WriteLine "Space Recovered: " & vbtab  &  FormatNumber(ByteCount/1024,2,,,True) & " KB"
	LogFile.WriteLine "Files Recovered: " & vbtab  & RecoverCount
	LogFile.WriteLine "Files Removed:" & vbtab & vbtab & DeleteCount
	LogFile.WriteBlankLines 1
	LogFile.WriteLine "Finish Time: " & Now()
	LogFile.Close
End If

ClearEnvironment

' Finished
WScript.Quit

'======================================================================

' Argument: Noone
Sub ClearEnvironment
	' Clear system memory
	Set FSys = Nothing
	Set wshShell = Nothing
	Set DocsStore = Nothing
	Set Counter = Nothing
	Set LogFile = Nothing
	Set ByteCount = Nothing
	Set RecoverCount = Nothing
	Set DeleteCount = Nothing
	Set oWS = Nothing
	Set LogFileName = Nothing
End Sub

' Argument: Directory
' Where Directory is the path to a folder
Sub ParseFolder(Directory)
	Dim xFolder	' Single Folder object
	Dim xFolders	' Folders object
	Dim sFolder	' Subfolders object

' Scan current directory for files
	ParseFiles Directory

' Scan current directory for subfiles, and parse each subfolder
	Set xFolder = FSys.GetFolder(Directory)
	Set xFolders = xFolder.SubFolders
	
	For Each sFolder in xFolders
		ParseFolder sFolder
	next

' Clear Memory
	Set xFolder = Nothing
	Set xFolders = Nothing
	Set sFolder = Nothing
End Sub

' Arguments: Directory
' Where Directory is the path to a folder
Sub ParseFiles(Directory)
	Dim xFolder		' Single Folder object
	Dim xFiles		' Files collection object
	Dim xFile		' Single File object
	Dim oFile		' Single File Object
	Dim DeleteFiles()	' List of files to delete
	Dim CopyFiles()		' List of files to copy
	Dim BaseName		' Working Variable
	Dim Index 		' Working Variable
	Dim BackupFile		' Working Variable
	Dim TrueFile		' Working Variable
	Dim DoCopyFile 		' Action Flag
	Dim DoDeleteFile	' Action Flag

' Retrieve Folder and files within
	Set xFolder = FSys.GetFolder(Directory)
	Set xFiles = xFolder.Files

' Initialize Arrays
	ReDim DeleteFiles(0)
	ReDim CopyFiles(0)

' Parse each file in the folder
	For Each xFile in xFiles
		' Only work on backup files
		if Left(xFile.Name,10) = "Backup of " then
			' Files all assumed to be Word files
			BaseName = Right(xFile.Name,LEN(xFile.Name)-10)
			BaseName = Left(BaseName, LEN(BaseName)-3) & "DOC"
			
			' If we have a matching file to the current backup file, Retrieve that file
			if FSys.FileExists(FSys.BuildPath(Directory,BaseName)) = True Then
				Set oFile = FSys.GetFile(FSys.BuildPath(Directory,BaseName))

' If the Original File's Date is Less than the Backup Copy's Date, and
				' the Original File's size is zero, then mark the backup to be copied
				' as the real file name, and then Deleted

if (oFile.DateLastModified > xFile.DateLastModified AND oFile.Size = 0 ) OR (oFile.DateLastModified < xFile.DateLastModified) Then
					Index = UBound(CopyFiles) + 1
					ReDim Preserve CopyFiles(Index)
					Index = Index - 1
					CopyFiles(Index) = xFile.Name & "|" & oFile.Name

If LogFileName <> "" Then
						LogFile.WriteLine "Directory: " & Directory
						LogFile.WriteLine "Master File: " & oFile.Name & " (" & oFile.DateLastModified & " -Size: " & oFile.Size & ")"
						LogFile.WriteLine "Backup File: " & xFile.Name & " (" & xFile.DateLastModified & " -Size: " & xFile.Size & ")"
						LogFile.WriteLine "Action: Replace Master with Backup and Delete Backup."
						LogFile.WriteBlankLines 1
					End If
					
					Index = UBound(DeleteFiles) + 1
					ReDim Preserve DeleteFiles(Index)
					Index = Index - 1
					DeleteFiles(Index) = xFile.Name

DoCopyFile = True
					DoDeleteFile = True
				else
					' If the original File is intact, then mark the backup for delete

Index = UBound(DeleteFiles) + 1
					ReDim Preserve DeleteFiles(Index)
					Index = Index - 1
					DeleteFiles(Index) = xFile.Name
					DoDeleteFile = True

If LogFileName <> "" Then
						LogFile.WriteLine "Directory: " & Directory
						LogFile.WriteLine "Master File: " & oFile.Name & " (" & oFile.DateLastModified & " -Size: " & oFile.Size & ")"
						LogFile.WriteLine "Backup File: " & xFile.Name & " (" & xFile.DateLastModified & " -Size: " & xFile.Size & ")"
						LogFile.WriteLine "Action: Master OK, Delete Backup."
						LogFile.WriteBlankLines 1
					End If
					
				end if
			else
				' If the Original doesn't exist, Mark the backup for copy and delete

Index = UBound(CopyFiles) + 1
				ReDim Preserve CopyFiles(Index)
				Index = Index - 1
				CopyFiles(Index) = xFile.Name & "|" & BaseName

If LogFileName <> "" Then
					LogFile.WriteLine "Directory: " & Directory
					LogFile.WriteLine "Master File: (No Master)"
					LogFile.WriteLine "Backup File: " & xFile.Name & " (" & xFile.DateLastModified & " -Size: " & xFile.Size & ")"
					LogFile.WriteLine "Action: Create Master from Backup and Delete Backup."
					LogFile.WriteBlankLines 1
				End If

Index = UBound(DeleteFiles) + 1
				ReDim Preserve DeleteFiles(Index)
				Index = Index - 1
				DeleteFiles(Index) = xFile.Name

DoCopyFile = True
				DoDeleteFile = True
			end if
		end if
	Next

'Copy Files
	if DoCopyFile = True Then
		For Index = 0 to UBound(CopyFiles)-1
			BackupFile = FSys.BuildPath(Directory,Left(CopyFiles(Index),InStr(1,CopyFiles(Index),"|")-1))
			TrueFile = FSys.BuildPath(Directory, Right(CopyFiles(Index),LEN(CopyFiles(Index))-InStr(1,CopyFiles(Index),"|")))
			if FSys.FileExists(TrueFile) = True Then FSys.DeleteFile TrueFile, True
			Set xFile = FSys.GetFile(BackUpFile)
			xFile.Copy TrueFile, True
			RecoverCount = RecoverCount + 1
		Next
	End If

'Delete Files
	If DoDeleteFile = True Then
		For Index = 0 To UBound(DeleteFiles)-1
			Set xFile = FSys.GetFile(Fsys.BuildPath(Directory,DeleteFiles(Index)))
			ByteCount = ByteCount + xFile.Size
			xFile.Delete True
			DeleteCount = DeleteCount + 1
		Next 
	End If

' Clear Memory
	Set xFolder = Nothing
	Set xFiles = Nothing
	Set xFile = Nothing
	Set oFile = Nothing
	ReDim DeleteFiles(0)
	ReDim CopyFiles(0)
	Set BaseName = Nothing
	Set Index  = Nothing
	Set BackupFile = Nothing
	Set TrueFile = Nothing
	Set DoCopyFile  = Nothing
	Set DoDeleteFile = Nothing
End Sub

Unless otherwise noted, this code is licensed according to the terms and conditions listed in our copyright notice.

Last Modification:
1/1/2001

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2010 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 9/9/2010 12:45:28 PM for Unknown