Dx21 - Script Library

Home

eZine

Coding

Software

Network Admin.

Home > Coding > Libraries > Script Library > View Item Info

	Back
	Scripting References

Change Windows XP Product Key

This script assists in the changing of the Windows XP product key. The script takes into consideration the differences in product activation from Windows XP original release and Windows XP SP1 and greater. Utility allows for new product key to be supplied via command line for a silent change, or from within the script as a user input. Script utilizes WMI to change the product key and activation status.

Option Explicit

'////////////////////////////////////////////////////////////////////////////
'Windows Product Key and Activation Reset
'Portions of this script were modified from the 
'Microsoft provided script which can be found at:
'http://support.microsoft.com/Default.aspx?kbid=328874
'////////////////////////////////////////////////////////////////////////////

Const CSDKey = "HKLM\SYSTEM\CurrentControlSet\Control\Windows\CSDVersion"
Const WinVerKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName"

Dim objShell
Dim intActions, vRetVal, strProdKey

'Create Objects
Set objShell = CreateObject("WScript.Shell")

'Set Run-Time Environment
intActions = 0

'Verify Platform
vRetVal = GetData(WinVerKey, "Unknown")
If vRetVal <> "Microsoft Windows XP" Then CleanEnv -1

'Verify new Product Key
If WScript.Arguments.Count = 0 Then
	strProdKey = InputBox("Enter New Product Key:" & vbCr & _
		"(like: ABCDE-FGHIJ-KLMNO-PRSTU-WYQZX)", "Change Product Key")
	If Trim(strProdKey) = "" Then CleanEnv -2
Else
	strProdKey = WScript.Arguments.Item(0)
End If
strProdKey = UCase(Trim(Replace(strProdKey, "-", "")))
If Len(strProdKey) <> 25 Then CleanEnv -2

'Verify Service Pack Level
vRetVal = GetData(CSDKey, -1)

'Reset Product Key
'Delete SP1 and greater registry information
If vRetVal => 256 Then DelOOBEKey

'Use WMI to reactivate
SetProductKey

'Exit
CleanEnv intActions
'----------------------------------------------------------
Sub CleanEnv(intExitCode)
	On Error Resume Next
	
	Set objShell = Nothing
	
	WScript.Quit intExitCode
End Sub

Function GetData(strRegKey, vDefault)
	Dim vReturn
	
	On Error Resume Next
	vReturn = objShell.RegRead(strRegKey)
	If Err.number <> 0 Then
		Err.Clear
		GetData = vDefault
	Else
		GetData = vReturn
	End If
End Function

Sub DelOOBEKey()
	On Error Resume Next
	
	objShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\WPAEvents\OOBETimer"
	If Err.number <> 0 Then Err.Clear
End Sub

Sub SetProductKey()
	Dim objProd, vResult
	
	For Each objProd In GetObject("winmgmts:{impersonationLevel=impersonate}").InstancesOf ("win32_WindowsProductActivation")
		vResult = objProd.SetProductKey(strProdKey)
	
		If Err.Number <> 0 Then
			intActions = Err.Number
			Err.Clear
		End If
	
	Next
	
	Set objProd = Nothing
End Sub

'*************************************************
'Return Values:
'
'	-1		=	Incorrect Windows Version
'	-2		=	Incorrect Product Key or No Product Key supplied
'	 0		= 	Script completed as expected
'	##		= 	WMI Error.  Task failed.
'*************************************************

'////////////////////////////////////////////////////////////////////////////
'This script Copyright ©2005 Dx21, LLC a Washington Limited Liability Company.
'All Rights Reserved.
'
'Use and liability of this script is covered in the online
'Copyright and Disclaimer notices found here:
'http://www.dx21.com/COPYRIGHT.ASP
'http://www.dx21.com/DISCLAIMER.ASP
'
'You must read these prior to using this script.
'Last modification: 01/27/2005
'////////////////////////////////////////////////////////////////////////////

Unless otherwise noted, this code is licensed according to the terms and conditions listed in our copyright notice.

Last Modification:
1/27/2005

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2010 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 9/9/2010 12:50:37 PM for Unknown